args Source, Target
local Result, List, What, Dest, Clear
local Cap = "Source: " ++ Source ++ ", Target: " ++ Target ++ "'"

Result = Inputdialog("~List=List??Green|Yellow|Red, What=Operation with Files from List??Copy|Move|Delete, Dest=Destination Path (for 'Copy' && 'Move' operations)??Source folder|Target folder, Clear=Clear List File after Treatment Finished??", Cap)

if(Result == 0)
	quit

if(List == "") do
	messagebox("ok error", "List file is not specified", "TreatFileList Script")
	quit
endif

if(What == "") do
	messagebox("ok error", "Operation is not specified", "TreatFileList Script")
	quit
endif

if(What != "Delete" && Dest == "") do
	Cap = "Destination folder is not specified"
	messagebox("ok error", Cap, "TreatFileList Script")
	quit
endif

if(What != "Delete") do
	if(Dest == "Source folder" && file.validpath(Source) != "1") do
		Cap = "Source path '" ++ Source ++ "' is invalid"
		messagebox("ok error", Cap, "TreatFileList Script")
		quit
	endif
	if(Dest == "Target folder" && file.validpath(Target) != "1") do
		Cap = "Target path '" ++ Target ++ "' is invalid"
		messagebox("ok error", Cap, "TreatFileList Script")
		quit
	endif
endif

Target = ifelse(Dest == "Source folder", Source, Target)
Source = scriptfolder ++ "\FileLists\" ++ List ++ ".tfl"

if(file.validpath(Source) != "1") do
	Cap = "List File '" ++ Source ++ "' does not exist"
	messagebox("ok error", Cap, "TreatFileList Script")
	quit
endif

local fh = file.open(Source, "r")

if(fh > 0) do
	for(not(file.eof(fh))) 
		Result = file.readstring(fh)
		if(Result != 0) do
			if(file.validpath(Result) != 1) do
				Cap = "File " ++ Result ++ " does not exist"
				if(messagebox("okcancel warning", Cap, "TreatFileList Script") == 0)
					quit

			endif

			if(What == "Copy") do
				file.copy(Result, Target)
			elseif(What == "Move") do
				file.move(Result, Target)
			elseif(What == "Delete") do
				file.delete(Result)
			endif
		endif

	endfor
else
	messagebox("ok error", "File not opened", "FILE plugin error")
	quit
endif

file.close(fh)

if(Clear == "1")
	file.delete(Source)